多用户Lotus Notes自动安装的实现方法

12/3/2006来源:Lotus Notes人气:10362

作为优秀的群件系统,Lotus Notes在国内有着很广泛的应用。但是对Notes初学者来说,安装和配置它并不是一件简单的事情,特别是在企业内部,如果有很多用户需要安装它,那将是一件很棘手的事情。本文就提供一种为大量用户定制安装并配置Lotus Notes客户端的方法。
这是几年前版本还是4.61时我尝试的一种方法,是否适用于5.0版本,我还没有完全测试它,欢迎读者共同商榷。
一、生成通用的客户端配置文件
虽然Lotus Notes的客户端需要定制安装和配置,但是其中的大部分配置信息是通用的,比如连接方式、指定连接的服务器等。因此我们可以生成一个基本配置,然后在其基础上根据不同用户稍加改动进行定制。我们可以选择一台标准配置的终端进行安装配置(选择企业内部普遍使用的机型和操作系统)。
安装单个Notes客户端,作为一个Notes管理员应该不是问题,限于篇幅,这里不作详细说明。缺省情况下启动后你看到的Notes工作界面有点杂乱无章:很多个工作台标签、在第一个工作台上排列着很多个数据库图标,可是实际情况可能是这样的,我们基于Lotus Notes开发办公系统专门为用户设计了新的界面(比如以某个数据库的导航器作为应用的主导航器),将各种功能进行了新的包装,并不需要用户去直接访问那些“个人邮箱”和“通讯录”等数据库。于是我们可以作如下一些设置:设置运行后直接进入某个数据库的导航器;安排工作台页面;为新邮件到来作提示等等很多个性化的设置(想象一下,如果这些都要手把手的教给每一个最终用户自己去配置,那是一件多么繁琐的事情)。所有这些,我们通过管理员事先的一次标准化配置,都记录在相应的配置文件当中。
最终我们将得到的三个有用的配置文件是,在/notes/data/目录下的:
desktop.dsk
names.nsf
以及在C:/windows目录下的:
notes.ini
有了这三个文件,为其他用户的安装配置就方便多了。当然,我们可以根据需要生成几套不同的配置文件,以针对不同部门或级别的用户安装。当然,个别信息需要针对每个不同的用户来配置,但至少这已经帮助我们减少了很多工作。
二、自动响应安装
实际上Lotus Notes提供了安装客户端的自动化功能(详见联机帮助)。它有一个自动化安装文件:INSTNOT.RSP,你可以在它的安装盘目录中找到。该文件中主要内容如下。(每个参数的含义都有英文说明,下文添加了一些中文注释以利表述)
[User Registration]
; 这一段参数用于指定最终用户的基本信息
UserName = AnyUser
CompanyName = MyCompany
[General Information]
; 这一段参数用于指定安装的类型和最终生成的程序组名称
InstallType = 1
PRogramGroup = 某企业办公系统
StartmenuFolder = 某企业办公系统
[NOT]
; 这一段参数用于指定Notes的目录信息,本示例中的参数均指定安装在C盘。
BASEDIR = c:\lotus
NOTDIR = c:\Notes
NOTWORKDIR = c:\Notes\Data
SizeOfInstall = 3
[CustomizeNOT]
; 这一段参数是当前面的SizeOfInstall = 3,即选择自定义安装类型后的具体描述
NOTESPROGRAM = 1
NOTESINTLDIC = 0
NOTESPDATA = 1
NOTESTEMPLATE = 0
NOTESDOCUMENT = 0
NOTESHELP = 0
NOTESHELPLITE = 0
NOTESVIEWER = 0
NOTESBROWSER = 0
NOTESBROWSERSUPPORT = 0
我们可以把这个文件作一个备份,然后根据需求定制它,还可以根据企业中的不同用户群定制多个响应文件以自动完成不同种类的安装配置,分别把它们命名为INSTNOT1.RSP 、INSTNOT2.RSP等,如何使用这些定制好的文件呢,它的注释已经说的很清楚了:
\install.exe /A
实际上在Notes安装目录中还有一个更为具体的定制安装文件,例如指定不安装某个模板文件,或者增加一个新的模板文件。这个文件就是NOTNODE.INF,它需要和安装目录的另一个文件Install.lst配合使用。这两个文件的使用方法本文不作具体描述,详见该文件内容以及联机帮助“为共享安装而定制安装文件”部分。
最后还需注意的是,把安装目录中的许可文件License.txt改名,这样,在安装开始的时候就不会出现许可协议的提示了。
三、批量生成用户标识符
通常情况下管理员可以用“分别注册新用户”方式为某个用户生成标识符,但是当需要生成大量用户标识符时,这可不是一件轻松的事情。好在Notes依然为我们提供了批量生成的方法。我们可以使用文本编辑器创建一个文本文件register.txt,包含用于每个用户的下列格式的标识符信息,一个用户一行:
Lastname;Firstname;MiddleInitial;organizational unit; passWord;IDfiledirectory;IDfilename; homeservername;mailfiledirectory;mailfilename;location;comment;forwarding address;profile name;local administrator
于是,我们可以为一个用户作如下注册定义:
张三;;;信息处;password;c:/notes/data/userid;zhangsan.id;domino/Harbin;;zhangsan.nsf;办公室;;;用户配置简要表1;
文件注册的方法是,从管理面板上,单击“个人”图标并选择“从文件注册”。详情可以参阅联机帮助Domino管理帮助部分的“从文本文件注册一组用户”一节。需要注意的是,在每个用户的注册信息中不要有换行符和回车符的存在。用户标识符生成以后,以适当的途径分发给每个用户。
四、一个简单的自动安装配置程序的实例
有了以上的准备,我们就可以利用各种编程手段(如VB)方便快速的制作一个自动安装配置程序。下面给出一个用DOS批处理命令写的简单的安装程序,旨在阐明具体思路。
假定满足以下条件:用户均在一个企业内部网中,Lotus Notes的安装程序已经放在一台FTP服务器的Notes目录下,该目录中同时包含有前面事先生成的三个配置文件。所有用户都有权访问该服务器。每个用户的标识符user.id均已发到手中。
程序清单如下:
@ECHO OFF
PATH C:\;C:\WINDOWS;C:\WINDOWS\COMMAND;%PATH%
CLS
ECHO ********************************
ECHO 莲花办公软件安装程序
ECHO ********************************
ECHO.
ECHO 1. 本安装程序适用于WINDOWS95或98,如果是NT请与管理员联系;
ECHO 2. 软件安装于C盘,需40M空间,安装过程还需暂时占用45M空间。
ECHO.
CHOICE " 如果满足以上条件并且您同意安装在C:盘,请按Y键,否则按N键:"
IF ERRORLEVEL 1 GOTO NEXT1
GOTO QUIT
:NEXT1
 
ECHO 创建临时文件夹
MD MYTEMP>NUL
CD MYTEMP>NUL
ECHO anonymous>setup.dat
ECHO aa@bb>>setup.dat
ECHO user anonymous>>setup.dat
ECHO aa@bb>>setup.dat
ECHO cd notes>>setup.dat
ECHO prompt>>setup.dat
ECHO binary>>setup.dat
ECHO mget *.*>>setup.dat
ECHO quit>>setup.dat
 
ECHO.
ECHO 开始下载安装文件,需要约*分钟时间,如果出错会有提示,请耐心等待....
FTP -v -s:setup.dat ftpserver>NUL
 
IF NOT EXIST INSTALL.EXE GOTO END1
ECHO.
ECHO 开始安装,请稍候....
INSTALL.EXE /A INSTNOT.RSP
 
:LOOP
ECHO.
CHOICE /C:Y " 注意:安装程序没有完成请不要干预!!! 完成后按Y键:"
IF ERRORLEVEL 1 GOTO NEXT2
GOTO LOOP
 
:NEXT2
SET ERRORLEVEL = 0
REM 此处为用户进行缺省配置
COPY NAMES.NSF C:\NOTES\DATA\NAMES.NSF>NUL
COPY DESKTOP.DSK C:\NOTES\DATA\DESKTOP.DSK>NUL
COPY NOTES.INI C:\WINDOWS\NOTES.INI>NUL
REM 如果当前执行批处理命令的目录下有用户标识符文件
REM 则将用户标识符文件拷贝到用户数据目录下
IF EXIST ..\*.ID COPY ..\*.ID C:\NOTES\DATA>NUL
IF ERRORLEVEL 1 GOTO END2
 
ECHO.
ECHO 安装成功!
GOTO END
 
:END1
ECHO.
ECHO 网络没有连通,下载安装文件失败,请与管理员联系。
GOTO END
 
:END2
ECHO.
ECHO 安装已完成,但初始化配置失败,请与管理员联系。
 
:END
ECHO.
IF NOT EXIST ..\MYTEMP\*.* GOTO QUIT
ECHO 删除临时文件夹
ECHO Y|DEL *.*>NUL
CD ..
RD MYTEMP
 
:QUIT
ECHO.
ECHO 结束!
通过以上安装程序,用户不必进行任何干预,喝杯咖啡的功夫,打开的工作台界面就等着他操作了。